*=====================================================================
      * Print Procedures
      *
      * Copyright (C) Julian Monypenny 1997
      *=====================================================================
     H NoMain
 
      *---------------------------------------------------------------------
      * Global definitions
      *---------------------------------------------------------------------
      /Copy ToolkitCpy,CmdH
      /Copy ToolkitCpy,PrtH
      /Copy ToolkitCpy,StdTypH
 
      *=====================================================================
     P DisplayPrt      B                   Export
      *=====================================================================
     D                 Pi                  Like( LglTyp )
     D  SplFil                             Like( NamTyp )  Value
 
     C                   Return    ExecCmd( 'DspSplF ' + SplFil + ' '  +
     C                                      'SplNbr( *Last )' )
 
     P                 E
 
      *=====================================================================
     P DeletePrt       B                   Export
      *=====================================================================
     D                 Pi                  Like( LglTyp )
     D  SplFil                             Like( NamTyp )  Value
 
     C                   Return    ExecCmd( 'DltSplF ' + SplFil + ' '  +
     C                                      'SplNbr( *Last )' )
 
     P                 E
 
      *=====================================================================
     P LinkPrt         B                   Export
      *=====================================================================
     D                 Pi                  Like( LglTyp )
     D  FilNam                             Like( NamTyp )  Value
     D  SplFil                             Like( NamTyp )  Value
     D  UsrDta_O                           Like( NamTyp )  Value
     D                                     Options( *NoPass )

     D  PrtOpts_O                          Like( StrTyp )  Value
     D                                     Options( *NoPass )
 
     D UsrDta          S                   Like( NamTyp )
     D PrtOpts         S                   Like( StrTyp )
 
     C                   If        %Parms   > 2
     C                   Eval      UsrDta   = UsrDta_O
     C                   EndIf
 
     C                   If        %Parms   > 3
     C                   Eval      PrtOpts  = PrtOpts_O
     C                   EndIf
 
     C                   Return    ExecCmd( 'OvrPrtF '  + FilNam  + ' '  +
     C                                      'SplFName(' + SplFil  + ') ' +
     C                                      'UsrDta('   + UsrDta  + ') ' +
     C                                      'DfrWrt( *Yes ) '            +
     C                                      'OvrScope( *Job ) '          +
     C                                       PrtOpts )
 
     P                 E
 
      *=====================================================================
     P UnlinkPrt       B                   Export
      *=====================================================================
     D                 Pi                  Like( LglTyp )
     D  FilNam                             Like( NamTyp )  Value
 
     C                   Return    ExecCmd( 'DltOvr ' + FilNam + ' '   +
     C                                      'Lvl( *Job )' )
 
     P                 E