*=====================================================================
      * Member Procedures
      *
      * Copyright (C) Julian Monypenny 1997
      *=====================================================================
     H NoMain
 
      *---------------------------------------------------------------------
      * Global definitions
      *---------------------------------------------------------------------
      /Copy ToolkitCpy,ApiErrH
      /Copy ToolkitCpy,MbrH
      /Copy ToolkitCpy,StdTypH
 
      *=====================================================================
     P MbrExists       B                   Export
      *=====================================================================
     D                 Pi                  Like( LglTyp )
     D  FilNam                             Like( NamTyp )  Value
     D  FilLib                             Like( NamTyp )  Value
      *   Name, *CURLIB, or *LIBL
     D  MbrNam                             Like( NamTyp )  Value
 
     C                   Return    GetMbrDsc( FilNam: FilLib:
     C                                        MbrNam: BrfMbrDscFmt:
     C                                        MbrDscDs )
 
     P                 E
 
      *=====================================================================
     P GetMbrDsc       B                   Export
      *=====================================================================
     D                 Pi                  Like( LglTyp )
     D  FilNam                             Like( NamTyp )  Value
     D  FilLib                             Like( NamTyp )  Value
      *   Name, *CURLIB, or *LIBL
     D  MbrNam                             Like( NamTyp )  Value
     D  DscFmt                             Like( ApiFmtTyp )  Value
     D  MbrDsc                             Like( MbrDscDs )
 
     D QFilNam         S                   Like( QNamTyp )
     D LibLst          S                   Like( ChrTyp )
     D FilOvr          S                   Like( ChrTyp )  Inz( *Off )
     D BrfMbrDscSiz    C                   135

     D DtlMbrDscSiz    C                   %Size( MbrDscDs )
 
     C                   Reset                   MbrDscDs
 
     C                   Eval      QFilNam   = FilNam + FilLib
 
     C                   If        FilLib    = '*LIBL'
     C                   Eval      LibLst    = *On
     C                   Else
     C                   Eval      LibLst    = *Off
     C                   EndIf
 
     C                   If        DscFmt    = BrfMbrDscFmt
     C                   Eval      MbrDscSiz = BrfMbrDscSiz
     C                   Else
     C                   Eval      MbrDscSiz = DtlMbrDscSiz
     C                   EndIf
 
     C                   Eval      MbrDsc    = MbrDscDs
 
     C                   Call      'QUSRMBRD'
     C                   Parm                    MbrDsc
     C                   Parm                    MbrDscSiz
     C                   Parm                    DscFmt
     C                   Parm                    QFilNam
     C                   Parm                    MbrNam
     C                   Parm                    FilOvr
     C                   Parm                    ApiErrDs
     C                   Parm                    LibLst
 
     C                   Return    ( ApiErrLen = 0 )
 
     P                 E