*=====================================================================
      * Character Procedures
      *
      * Copyright (C) Julian Monypenny 1997
      *=====================================================================
     H NoMain
 
      *---------------------------------------------------------------------
      * Global definitions
      *---------------------------------------------------------------------
      /Copy ToolkitCpy,ChrH
      /Copy ToolkitCpy,StdConH
      /Copy ToolkitCpy,StdTypH
 
      *=====================================================================
     P IsAlNumChr      B                   Export
      *=====================================================================
     D                 Pi                  Like( LglTyp )
     D  Chr                                Like( ChrTyp )  Value
 
     C                   If        Chr >= 's'  And  Chr <= 'z'  Or
     C                             Chr >= 'j'  And  Chr <= 'r'  Or
     C                             Chr >= 'a'  And  Chr <= 'i'  Or
     C                             Chr >= 'S'  And  Chr <= 'Z'  Or
     C                             Chr >= 'J'  And  Chr <= 'R'  Or
     C                             Chr >= 'A'  And  Chr <= 'I'  Or
     C                             Chr >= '0'  And  Chr <= '9'
     C                   Return    *On
     C                   Else
     C                   Return    *Off
     C                   Endif
 
     P                 E
 
      *=====================================================================
     P IsAlphaChr      B                   Export
      *=====================================================================
     D                 Pi                  Like( LglTyp )
     D  Chr                                Like( ChrTyp )  Value
 
     C                   If        Chr >= 's'  And  Chr <= 'z'  Or
     C                             Chr >= 'j'  And  Chr <= 'r'  Or
     C                             Chr >= 'a'  And  Chr <= 'i'  Or
     C                             Chr >= 'S'  And  Chr <= 'Z'  Or

     C                             Chr >= 'J'  And  Chr <= 'R'  Or
     C                             Chr >= 'A'  And  Chr <= 'I'
     C                   Return    *On
     C                   Else
     C                   Return    *Off
     C                   Endif
 
     P                 E
 
      *=====================================================================
     P IsNumChr        B                   Export
      *=====================================================================
     D                 Pi                  Like( LglTyp )
     D  Chr                                Like( ChrTyp )  Value
 
     C                   If        Chr >= '0'  And  Chr <= '9'
     C                   Return    *On
     C                   Else
     C                   Return    *Off
     C                   Endif
 
     P                 E
 
      *=====================================================================
     P IsLowerChr      B                   Export
      *=====================================================================
     D                 Pi                  Like( LglTyp )
     D  Chr                                Like( ChrTyp )  Value
 
     C                   If        Chr >= 's'  And  Chr <= 'z'  Or
     C                             Chr >= 'j'  And  Chr <= 'r'  Or
     C                             Chr >= 'a'  And  Chr <= 'i'
     C                   Return    *On
     C                   Else
     C                   Return    *Off
     C                   Endif
 
     P                 E
 
      *=====================================================================
     P IsUpperChr      B                   Export
      *=====================================================================
     D                 Pi                  Like( LglTyp )
     D  Chr                                Like( ChrTyp )  Value

 
     C                   If        Chr >= 'S'  And  Chr <= 'Z'  Or
     C                             Chr >= 'J'  And  Chr <= 'R'  Or
     C                             Chr >= 'A'  And  Chr <= 'I'
     C                   Return    *On
     C                   Else
     C                   Return    *Off
     C                   Endif
 
     P                 E
 
      *=====================================================================
     P ToLowerChr      B                   Export
      *=====================================================================
     D                 Pi                  Like( ChrTyp )
     D  Chr                                Like( ChrTyp )  Value
 
     C                   If        Chr >= 'S'  And  Chr <= 'Z'  Or
     C                             Chr >= 'J'  And  Chr <= 'R'  Or
     C                             Chr >= 'A'  And  Chr <= 'I'
     C                   BitOff    '1'           Chr
     C                   Endif
 
     C                   Return    Chr
 
     P                 E
 
      *=====================================================================
     P ToUpperChr      B                   Export
      *=====================================================================
     D                 Pi                  Like( ChrTyp )
     D  Chr                                Like( ChrTyp )  Value
 
     C                   If        Chr >= 's'  And  Chr <= 'z'  Or
     C                             Chr >= 'j'  And  Chr <= 'r'  Or
     C                             Chr >= 'a'  And  Chr <= 'i'
     C                   BitOn     '1'           Chr
     C                   Endif
 
     C                   Return    Chr
 
     P                 E
 
      *=====================================================================

     P ChrToInt        B                   Export
      *=====================================================================
     D                 Pi                  Like( IntTyp )
     D  Chr                                Like( ChrTyp )  Value
 
     D Int             S                   Like( IntTyp )
     D BinDs           Ds                  Inz
     D  BinInt                             Like( SmlBinTyp )
     D   BinChr                            Like( ChrTyp )
     D                                     Overlay( BinInt: 2 )
 
     C                   Eval      BinChr  = Chr
     C                   Eval      Int     = BinInt
 
     C                   Return    Int
 
     P                 E
 
      *=====================================================================
     P IntToChr        B                   Export
      *=====================================================================
     D                 Pi                  Like( ChrTyp )
     D  Int                                Like( IntTyp )  Value
 
     D Chr             S                   Like( ChrTyp )
     D BinDs           Ds                  Inz
     D  BinInt                             Like( SmlBinTyp )
     D   BinChr                            Like( ChrTyp )
     D                                     Overlay( BinInt: 2 )
 
     C                   Eval      BinInt  = Int
     C                   Eval      Chr     = BinChr
 
     C                   Return    Chr
 
     P                 E