H            D
     FDSPI11  CF  E                    WORKSTN
     FFICH1L0 UF  E           K        DISK
     FFICH2P1 IF  E           K        DISK
     FFICH1PV UF  E           K        DISK                      A
     I              'ENREGISTREMENT VERRO-C         M1
     I              'UILLÉ PAR'
     I              'LE :'                C         M2
     I           SDS
     I                                      244 253 SDSECR
     IDATC        DS
     I I                                      1   60DATVER
      * PGM PRINCIPAL (BOUCLE SUR IMAGE 1)
      * ==================================
     C                     WRITETITRE
     C                     EXFMTF1
     C           *IN03     DOWEQ*OFF
     C                     EXSR TRTF1
     C                     EXFMTF1
     C                     ENDDO
     C                     MOVE *ON       *INLR
      * DEBUT DES SOUS PROGRAMMES
      * =========================
     C           TRTF1     BEGSR
     C           CLE       CHAINFICH1FV              65
     C           *IN65     IFEQ *OFF
      * ENREGISTREMENT VERROUILLÉ
     C                     UNLCKFICH1PV
     C           M1        CAT  ECRAN:1   MSG       P
     C                     CAT  M2:1      MSG
     C                     CAT  DATC:1    MSG
     C                     MOVE *ON       *IN60
     C                     ELSE
      * LECTURE SEULE  -----------------------------V
     C           CLE       CHAINFICH1F1             N50
     C           *IN50     IFEQ *OFF
     C                     MOVE SDSECR    ECRAN
     C                     Z-ADDUDATE     DATVER
     C                     WRITEFICH1FV
     C                     EXSR TRTF2
     C           CLE       DELETFICH1FV              90
     C                     ENDIF
     C                     ENDIF
     C                     ENDSR

      *
     C           TRTF2     BEGSR
     C           ERROR     DOUEQ'NON'
     C                     EXFMTF2
     C                     SELEC
     C           *IN12     WHEQ *ON
     C                     LEAVE
     C                     OTHER
     C                     EXSR CTLF2
     C           ERROR     IFEQ 'NON'
      * ACCES AU FICHIER EN MISE   JOUR (ON PERD LA SAISIE UTILISATEUR)
     C           CLE       CHAINFICH1F1              50
      * RELECTURE DU BUFFER ECRAN (RETROUVE MISES A JOUR UTILISATEUR)
      * (SANS ACTION CLAVIER CAR "RTNDTA" DANS LE DSPF)
     C                     READ F2                       90
      * MISE A JOUR FICHIER ET DEVERROUILLAGE
     C                     UPDATFICH1F1
     C                     ENDIF
     C                     ENDSL
     C                     ENDDO
     C                     ENDSR
      *
     C           CTLF2     BEGSR
     C                     MOVE 'NON'     ERROR   3
      * CONTROLE DU CODE
     C           CODE      CHAINFICH2F1              51
     C           *IN51     IFEQ *ON
     C                     MOVE 'OUI'     ERROR
     C                     ENDIF
      * AUTRES CONTROLES DE VALIDITE
     C*          .....     IF.. .....
     C*                    MOVE 'OUI'     ERROR
     C*                    MOVE *ON       *IN..
     C*                    ENDIF
     C                     ENDSR