H DFTACTGRP(*NO) ACTGRP(*CALLER) THREAD(*SERIALIZE)
 
     D StringversCH    PR         32767    VARYING
     D                                      EXTPROC(*JAVA :'java.lang.String':
     D                                                  'getBytes')
 
     D newString       PR              O   EXTPROC(*JAVA : 'java.lang.String':
     D                                                     *CONSTRUCTOR)
     D                               30A   CONST VARYING
 
 
     D maChaine1       S               O   CLASS(*JAVA : 'java.lang.String')
     D maChaine2       S               O   CLASS(*JAVA : 'java.lang.String')
     D chaineRT        S             40    VARYING
 
 
     D StrEquals       PR              N   EXTPROC(*JAVA :'java.lang.String':
     D                                                  'equalsIgnoreCase')
     D                                 O   CLASS(*JAVA : 'java.lang.String')
 
     D Inverserchaine  PR              O   EXTPROC(*JAVA : 'Invert':
     D                                      'inverserChaine')
     D                                     STATIC
     D                                     CLASS(*JAVA : 'java.lang.String')
     D                                 O    CLASS(*JAVA : 'java.lang.String')
 
      /free
        maChaine1 = newstring('test1');
        maChaine2 = newstring('test2');
         if StrEquals(maChaine1 : maChaine2) ;
            dsply 'identiques' ;
          else;
            dsply 'différents';
         endif;
         machaine2 = Inverserchaine(maChaine1);
         chainert = StringVersCH(machaine2);
         dsply chainert;
        *inlr = *on;
      /end-free