PGM        PARM(&LIB &OWN)
             DCL        VAR(&LIB) TYPE(*CHAR) LEN(10)
             DCL        VAR(&OWN) TYPE(*CHAR) LEN(10)
             DCL        VAR(&EOF) TYPE(*LGL)
             DCLF       FILE(QADSPOBJ)
/* DCL MSG*/ INCLUDE    SRCMBR(CHGPINC1)
 
             CHKOBJ     OBJ(&LIB) OBJTYPE(*LIB) AUT(*USE)
             SELECT
              WHEN (&OWN *NE '*CURRENT') THEN( +
               CHKOBJ     OBJ(&OWN) OBJTYPE(*USRPRF) )
              OTHERWISE  CMD(RTVJOBA USER(&OWN))
             ENDSELECT
 
             DSPOBJD    OBJ(&LIB/*ALL) OBJTYPE(*ALL) +
                          OUTPUT(*OUTFILE) OUTFILE(QTEMP/CHGPROP)
             OVRDBF     FILE(QADSPOBJ) TOFILE(QTEMP/CHGPROP)
 
             CALLSUBR   LECTURE
             DOWHILE    COND(*NOT &EOF)
              CHGOBJOWN  OBJ(&ODLBNM/&ODOBNM) OBJTYPE(&ODOBTP) +
                           NEWOWN(&OWN)
              CALLSUBR LECTURE
             ENDDO
 
             SNDPGMMSG  MSG(&OWN *BCAT 'est propriétaire de tous les +
                          objets de la bibliotheque ' *CAT &LIB) +
                          MSGTYPE(*COMP)
 
/*MESSAGES*/ INCLUDE    SRCMBR(CHGPINC2)
SUBR       SUBR(LECTURE)
             RCVF
              MONMSG     MSGID(CPF0864) EXEC(CHGVAR VAR(&EOF) +
                          VALUE('1'))
ENDSUBR
 
ENDPGM